Konvertierung zum AF5 2


Kurzfassung:


Konverter herunterladen

Der af5-mqo-to-tgc Konverter wandelt die *.mqo Datei in eine geschützte *.tgc Datei um. Dieser Konverter arbeitet nur in eine Richtung, d.h. eine .tgc Datei lässt sich nicht wieder zurück in eine mqo Datei konvertieren. Dies dient zum Schutz der erstellten und teilweise von IPACS gekauften 3D Modelle.
Um auch die Texturen zu verschlüsseln gibt es einen weiteren Konverter, den af5-makemaps.
-> AeroFly 5 Entwicklertools


Batch erstellen

Um sich das Leben einfacher zu gestalten, habe ich mir eine Batch-Datei (*.bat) erstellt.
Dazu wird zunächst ein *.txt Textdokument mit belibigen Namen erstellt. Sinnvoll wäre z.B. MODELLNAME-to-af5.txt. In das Textdokument schreibt man folgenden Text und ersetzt danach MODELLNAME durch den Namen der zu konvertierenden *.mqo Datei:

af5-mqo-to-tgc MODELLNAME 1.000

Die Zahl gibt den Maßstab an, mit dem das Modell umgerechnet wird. Den Faktor werde ich evtl. später noch weiter erklären.
Die Textdatei wird nun abgespeichert und in *.bat umbenannt. Nun werden die af5-mqo-to-tgc.exe, die MODELLNAME-to-af5.bat, die Lizenz (*.lic) und das 3D Modell (*.mqo) allesamt in einen Ordner verschoben, am besten einfach den Ordner des 3D Modells.
Jetzt kann die Batch-Datei ausgeführt werden. Es öffnet sich ein Komandofenster, das nach Beendigung der Umwandlung mit einem Tastendruck geschlossen wird.
Der Konverter generiert außer der *.tgc auch die tm.log, in der das gesamte Protokoll der Umwandlung geschrieben wurde.


Textur umwandeln

Anschließend wird noch die Textur vom 3D Modell umgewandelt. Dazu werden die Texturen _color, alpha, _bump und _gloss in den Installationsordner des af5-makemaps Konverters kopiert und dort umgewandelt, indem die Exe ausgeführt wird. Danach werden die umgewandelten *.ttx Dateien in den Modellordner geschoben.


Batch für alles

Diese Batch-Datei wandelt sowohl das 3D Modell (mqo) als auch die Texturen (bmp und tif) um.
Hier können Sie den Quellcode als txt herunterladen. Sie müssen dann nurnoch die Datei mit einem Texteditor öffnen und bei MAPSCONVERTER den exakten Installationspfad des Ipacs AF5-Makemapskonverters einfügen und bei MQOSIZE den Skalierungsfaktor für die Umwandlung des 3D Modells angeben. Danach speichern sie die Datei als .bat ab, damit Sie sie per Doppelklick ausführen können.
Das Batchprogramm muss sich zusammen mit dem af5-mqo-to-tgc.exe und der Lizenzdatei im Ordner des Mqo-3D-Modells befinden.

Quellcode:

@echo off
:: Schaltet die Pfadangaben aus. (Mit einem zweifachen Doppelpunkt wird eine Kommentarzeile markiert)

:: --------------------  ACHTUNG!  --------------------
:: Tragen Sie den Pfad des IPACS-af5-makemaps Installationsordners nach dem Gleichheitszeichen ein:
set MAPSCONVERTER=C:\Users\Normal\AppData\Local\IPACS-af5-makemaps

:: --------------------  ACHTUNG!  --------------------
:: Tragen Sie hier nach dam Gleichheitszeichen den Skalierungsfaktor ein:
set MQOSIZE=1.000

set USERAIRCRAFT=%cd%
:: Der aktuelle Pfad wird als Modellpfad angenommen, er wird automatisch ermittelt

cd %USERAIRCRAFT%

:: Die folgende Schleife ermittelt den Verzeichnisnamen, in dem die Batch liegt. 
:: So wie der Ordner heißt sollte auch die MQO-Datei heißen
for %%* in (.) do set MQONAME=%%~n*

echo.
:: Gibt eine Leerzeile aus
:: echo gibt Text aus

echo.
echo /--------------------------------------------------------
echo /
echo /    %0  
echo /
echo /    ----------------------------------------------------
echo /    /    Aerofly 5 Konverter-Launcher Version 1.0      /
echo /    /                                                  /
echo /    /    Quelle: http://aerofly-sim.de/                /
echo /    /    Autor: Jan-Hendrik Hanuschik (Jet-Pack)       /
echo /    ----------------------------------------------------
echo /
echo /    Diese Batch erfordert af5-mqo-to-tgc.exe und af5-makemaps.exe,
echo /    diese Konverter können Sie sich zusammen mit den anderen Entwicklertools herunterladen:
echo /    http://www.aerofly.de/tools_de.html
echo / 
echo /    Die Verwendung dieses Programms geschieht auf eigene Gefahr hin!
echo /    Der Autor kann nicht dafuer garantieren, dass das Programm fehlerfrei laeuft.
echo /    Erstellen Sie deshalb bitte stets vorher ein Backup.
echo /    Eine Weitergabe dieses Programms darf nur fuer private Zwecke dienen, 
echo /    dabei wird darum gebeten die Quelle anzugeben.
echo /    Die kommerzielle Nutzung und eine Veroeffentlichung ohne die Einstimmung des Autors sind 
echo /    ausgeschlossen.
echo /
echo --------------------------------------------------------
echo.
echo      Es wird nun nach der %MQONAME%.MQO Datei gesucht.
echo      Wenn sie gefunden wird, wird der Konverter automatisch gestartet...
echo.
call :MQOSEARCH 
:: ruft die Sprungmarke "mqosearch" auf


call :END
:: ruft die Sprungmarke "end" auf

:: --------------------
:: Sprungmarke "mqosearch" - Hier wird nach der evtl. vorhandenen MQO gesucht, damit diese Konvertiert werden kann.
:: --------------------
:MQOSEARCH
cd "%USERAIRCRAFT%"
echo      Suche nach %MQONAME%.mqo ...
echo      Dateipfad: %USERAIRCRAFT%\%MQONAME%.mqo
echo.

if exist %MQONAME%.mqo (
	goto :CONVERTMQO
) else ( goto :MQONOTFOUND )

:MQONOTFOUND
echo.      --- ERROR ---
echo      Das MOQ-3D-Modell wurde nicht gefunden. 
echo      Bitte ueberpruefen Sie die eingegebenen Pfade in der Batch-Datei.
echo      Der Fehler wird ignoriert, es wird mit der Umwandlung der Texturen begonnen.
echo.
echo      [debug]: %USERAIRCRAFT%\%MQONAME%.mqo NOT found
echo.
echo --------------------------------------------------------
echo.
goto :CONVERTTEXTURES
:: Springe weiter zur Sprungmarke CONVERTTEXTURES


:: --------------------
:: Sprungmarke "convertmqo" - Konvertiert die MQO, wenn sie gefunden wurde
:: --------------------
:CONVERTMQO
echo      %MQONAME%.mqo gefunden! :D
echo      Starte Konverter...
echo.
echo --------------------------------------------------------
echo.

cd "%USERAIRCRAFT%"
::wechselt zum Verzeichnis des Modells (nur um sicher zugehen...)

af5-mqo-to-tgc %MQONAME% %MQOSIZE%
:: startet den Konverter, verwendet den Verzeichnisnamen als MQO-Namen 
:: und die Variable MQOSIZE als Skalierungsfaktor
:: Der Skalierungsfaktor wird am Anfang dieser Datei definiert.

echo.
echo --------------------------------------------------------
echo.
echo      af5-mqo-to-tgc Konverter wurde beendet  
echo      Wandle nun alle Texturfiles um.
echo.
echo --------------------------------------------------------
echo.
goto :CONVERTTEXTURES

:: --------------------
:: Sprungmarke "converttextures" - kopiert alle bmps aus dem Modellordner, wandelt diese um
:: und verschiebt die ttx in den Modellordner.
:: --------------------
:CONVERTTEXTURES

cd %USERAIRCRAFT%
for %%i in (bmp tif) do copy %USERAIRCRAFT%\*.%%i %MAPSCONVERTER%

cd %MAPSCONVERTER%
af5-makemaps.exe *

move %MAPSCONVERTER%\*.ttx %USERAIRCRAFT%
for %%i in (bmp tif) do del %MAPSCONVERTER%\*.%%i 
echo.
echo --------------------------------------------------------
echo.
echo      Textur-Konverter wurde beendet.
echo      Programm wird jetzt geschlossen.
echo.
echo --------------------------------------------------------
echo.
goto :END

:: --------------------
:: Sprungmarke "end" - schließt das Programm
:: --------------------
:END
pause
cd %USERAIRCRAFT%
:: geht zurück zum Ausgangsverzeichnis
@echo on
exit

Wie geht es weiter?

TMC Datei anpassen


Leave a comment

Your email address will not be published. Required fields are marked *

I accept that my given data and my IP address is sent to a server in the USA only for the purpose of spam prevention through the Akismet program.More information on Akismet and GDPR.

This site uses Akismet to reduce spam. Learn how your comment data is processed.

2 thoughts on “Konvertierung zum AF5